Type

Aus VBA-wiki
Zur Navigation springen Zur Suche springen

Definition

Der benutzerdefinierte Datentyp Type ist tatsächlich kein eigener Datentyp, sondern stellt die Möglichkeit zur Verfügung, eine Gruppe von Eigenschaften und Werten zusammenzufassen:

Option Explicit

Private Type tpeUserData
    FirstName As String
    LastName As String
    BirthDate As Date
End Type

Achtung: Der VBA-Editor ergänzt nicht, wie bei Sub, Function und Property, automatisch das End Type. Bitte denken Sie daran, dies selbst zu tun!

  • Bei der Definition wird lediglich angegeben, welche Bestandteile der Type besitzen soll, also die Struktur definiert.
  • Ein Type kann nur in einem Modul (einer Klasse, einem UserForm) definiert werden, nicht in einer Prozedur.
  • Er kann nur im Kopf des Moduls (der Klasse, der UserForm) definiert werden, wie eine modulweite Variable.

Hierbei gilt folgendes:

  • Private beschränkt den Einsatz auf das Modul (die Klasse, die UserForm), in dem der Type definiert wurde
  • Public (ausschließlich in Modulen!) erweitert den Einsatz auf das gesamte Projekt

Bitte beachten: Ein benutzerdefinierter Datentyp muss mindestens ein Element enthalten.

Deklaration

Private Sub WorkWithType()
    Dim myData As tpeUserData
End Sub

Verwendung

Private Sub WorkWithType()
    Dim myData As tpeUserData
    
    myData.FirstName = "Max"
    myData.LastName = "Muster"
    myData.BirthDate = "1966-03-05"
End Sub

Als Rückgabewert einer Funktion

Private Function LoadUserData() As tpeUserData
    
    LoadUserData.FirstName = "Max"
    LoadUserData.LastName = "Muster"
    LoadUserData.BirthDate = "1966-03-05"
End Function

Als Übergabeparameter

Wichtig: Die Übergabe eines benutzerdefinierten Datentyps kann ausschließlich 'ByRef' erfolgen!

Private Sub WriteUserData(ByRef thisData As tpeUserData)
    
    Debug.Print thisData.FirstName & " " & thisData.LastName Debug.Print thisData.BirthDate
End Sub

Verschachtelte Anwendung

Im folgenden Beispiel bestehen die Dokumentdaten eines Briefes aus Autorendaten und zwei möglichen Unterschriften.

  • Anstatt alle Daten einzeln in einem benutzerdefinierten Datentyp unterzubringen, werden hier die Autorendaten getrennt von den Unterschriften definiert.
  • Im Datentyp der Dokumentdaten selbst wird lediglich eine neue Eigenschaft, das Datum, definiert und der Autor wird als tpeAuthorData deklariert.
  • Die insgesamt zwei möglichen Unterschriften erhalten beide den Datentyp tpeSignature.
Option Explicit

Private Type tpeAuthorData
    FirstName As String
    LastName As String
    Phone As String
    Fax As String
    EMail As String
End Type

Private Type tpeSignature
    FirstName As String
    LastName As String
    Department As String
End Type

Private Type tpeDocumentData
    Date As String
    Author As tpeAuthorData
    Signature As tpeSignature
    AdditionalSignature As tpeSignature
End Type

Bitte beachten: Folgende Reihenfolge muss bei verschachtelten Datentypen eingehalten werden: Der benutzerdefinierte Datentyp, welcher Elemente eines anderen Datentyps enthält (tpeDocumentData), muss im Code unterhalb der Definition des enthaltenen Datentyps definiert werden (tpeAuthorData und tpeSignature).

In einer Prozedur werden Teile der oben dargestellten Struktur wie folgt mit Daten gefüllt:

Private Sub LoadData()
    Dim myDocData As tpeDocumentData
    
    myDocData.Date = Date
    myDocData.Author.FirstName = "Max"
    myDocData.Author.LastName = "Muster"
End Sub

Types und Datenfelder

Der benutzerdefinierte Datentyp kann NICHT als Element in eine Collection aufgenommen werden.

Die Bildung eines Arrays mit Elementen eines benutzerdefinierten Datentyps ist hingegen möglich.

Die einzelnen Elemente eines benutzerdefinierten Datentyps können neben den natürlichen Datentypen auch eine Collection oder ein Array aufnehmen:

Private Type tpeMyType 
    CollectionEntries As Collection 
    ArrayEntries() As String 
End Type

Alternative

Alternativ zum benutzerdefinierten Datentyp können Sie eine Datenklasse einsetzen, um zusammengesetzte Datengruppen handhaben zu können.

Bitte beachten Sie dazu den Vergleich zwischen Datenklasse und 'Type'.