For-Schleifen

Einfache For-Schleife

Sub ForNext()
   Dim strCharacter As String
   
   ' Voraussetzung: Dem Entwickler oder dem angesprochenen Objekt
   ' ist die Anzahl der Elemente bekannt
   
   ' Grundgerüst: Zähler (bitte auf Größe achten!!!)
   Dim lngIndex As Long
   
   ' Grundgerüst: 
   ' For Zähler = Anfang To Ende
       ' Code
   ' Next Zähler
   
   
   ' Vom Entwickler vorgegebene Anfangs- und Endwerte
   For lngIndex = 3 To 17
       Debug.Print lngIndex
   Next lngIndex
   
   
   ' Die Eigenschaft 'Count' einer Auflistung enthält die Anzahl der Elemente
   For lngIndex = 1 To ActiveDocument.Characters.Count
       strCharacter = ActiveDocument.Characters.Item(lngIndex)
       Debug.Print strCharacter
   Next lngIndex
   
End Sub

Verhalten in verschiedenen Situationen

Standardsituation:

   For lngIndex = 1 To 3
       Debug.Print lngIndex        ' 1, 2, 3
   Next lngIndex
   Debug.Print lngIndex            ' 4

Anfangs- und Endwert sind gleich: Wird trotzdem einmal durchlaufen

   For lngIndex = 1 To 1
       Debug.Print lngIndex        ' 1
   Next lngIndex
   Debug.Print lngIndex            ' 2

Anfangswert ist geringer als Endwert: Schleife wird nicht betreten!

   For lngIndex = 1 To 0
       Debug.Print lngIndex        ' Schleife wird nicht betreten
   Next lngIndex
   Debug.Print lngIndex            ' 1

Step

Mit dem zusätzlichen Schlüsselwort 'Step' können wie in diesem Beispiel Elemente übersprungen werden:

Sub ForNextStep()

   ' Beispiel: Tabellenzeilen abwechselnd färben
   Dim lngRow As Long
   Dim tblTable As Table
   
   ' Table ist ein Objekt und wird mit 'Set' zugewiesen
   Set tblTable = Selection.Tables.Item(1)
   
   ' Mit 'Step 2' wird bei 'Next' dem Zähler 2 hinzugezählt

   For lngRow = 1 To tblTable.Rows.Count Step 2
       tblTable.Rows.Item(lngRow).Shading.BackgroundPatternColor = -721354855
   Next lngRow
End Sub

Step -1

Die Rückwärts-Schleife wird zum Löschen einzelner Elemente aus einer Auflistung verwendet:

 Sub ForNextStepMinus1()
   
   Dim lngRow As Long
   Dim tblTable As Table
   
  ' Die Word-Tabelle ist ein Objekt und wird mit 'Set' zugewiesen
   Set tblTable = Selection.Tables.Item(1)
   
   ' Mit 'Step -1' wird bei 'Next' die nächst obere Zeile verwendet
   ' Dies ist beim Löschen von Elementen aus einer Liste der einzig verwendbare Weg
   ' Hierbei den Anfangs- und Endpunkt vertauschen,
   ' also: For Zähler = Endpunkt To Anfangspunkt Step -1
   
   For lngRow = tblTable.Rows.Count To 1 Step -1
       tblTable.Rows.Item(lngRow).Delete
   Next lngRow
 End Sub

Step 0.1

Auf diesem Wege ist es möglich, in nicht Ganzzahligen Schritten durch die Schleife zu schreiten:

 Sub StepOneTenth()
    Dim dblIndex As Double
    
    For dblIndex = 0.3 To 1.2 Step 0.1
        Debug.Print dblIndex
    Next dblIndex
 End Sub

For Each

Mit dem Schlüsselwort 'Each' erübrigt sich die Verwendung einer Laufvariablen. Stattdessen wird das einzelne Element der Auflistung direkt angesprochen. Voraussetzung hierfür ist, dass eine entsprechende Variable vorbereitet wurde, um das Element entgegenzunehmen.

Hinter dem Schlüsselwort 'In' erscheint dann die Auflistung, aus welcher die Elemente stammen.

Bitte beachten: Eine 'For Each'-Schleife kann nur bei Auflistungen angewendet werden, die Objekte enthalten!

Private Sub ForEach()
   Dim lngIndex As Long
   Dim rowTable As Row
   Dim tbl As Table
   
   Set tbl = ActiveDocument.Tables.Item(1)
   
   For Each rowTable In tbl.Rows
       Debug.Print rowTable.Cells(1).Range.Text     ' Laufvariable muss bei For Each ein Variant bzw. ein Objekt sein!
   Next rowTable
   
   ' Als reguläre For-Schleife:
   
   For lngIndex = 1 To tbl.Rows.Count
       Set rowTable = tbl.Rows.Item(lngIndex)
       Debug.Print rowTable.Cells(1).Range.Text
   Next lngIndex
End Sub

Bitte beachten: Wenn die Bearbeitung der Elemente in einer bestimmten Reihenfolge erfolgen soll, welche dem Index entspricht, verwenden Sie besser die einfache For-Schleife.

Elemente löschen: 'For Each' vs. 'Step -1'

Die 'For Each'-Schleife kann in vielen Situationen ebenso gut wie die 'Step -1'-Schleife eingesetzt werden, um Elemente aus einer Auflistung zu löschen.

Je nach Auflistung, auf die zugegriffen wird, kann sich die 'For Each'-Schleife jedoch als unzureichend erweisen. Wenn Sie zum Beispiel einzelne Arbeitsblätter einer Arbeitsmappe löschen, passt sich die 'For Each'-Schleife insofern an, dass keine Elemente ausgelassen werden, wie es bei der regulären 'For Next'-Schleife durchaus passieren kann.

In diesem folgenden Fall jedoch verhält sich die 'For Each'-Schliefe genau wie die 'For Next'-Schleife und ist somit unzureichend:

   Sub DeleteRowsMarkedX()
       Dim rngCell As Range
       
       ' Beispiel: Excel Zeilen bedingt löschen
       ' For Each löscht keine aufeinander folgenden Zeilen,
       ' zweiter Treffer wird übersprungen
       For Each rngCell In Range("A1:A10")
           If rngCell.Text = "x" Then rngCell.EntireRow.Delete
       Next rngCell
   End Sub

In diesem Beispiel sollen die Zeilen, die in der ersten Spalte mit einem 'x' gekennzeichnet sind, komplett gelöscht werden. Die 'For Each'-Schleife durchläuft die Zeilen einer Tabelle wie eine reguläre For-Schleife und überspringt somit Zeilen, wenn vorangegangene Zeilen gelöscht wurden:

Wenn in der ersten Spalte a, x, b, c, x, d, x, e, f, g eingetragen war, wird die Liste korrekt auf a, b, c, d, e, f, g gekürzt. Wenn jedoch a, x, x, b, c, x, x, d, x, e eingetragen wurde, bleibt a, x, b, c, x, d, e übrig.

Die Rückwärts-Schleife kann dagegen immer jedes Element einer Auflistung betrachten, weil gelöschte Elemente 'hinter' ihr liegen. Sie wird daher auf jeden Fall korrekte Ergebnisse erzielen:

   Sub DeleteRowsMarkedX()
       Dim rngCell As Range
       Dim lngIndex As Long
       
       For lngIndex = Range("A1:A10").Rows.Count To 1 Step -1
           Set rngCell = Range("A1:A10").Cells(lngIndex)
           If rngCell.Text = "x" Then rngCell.EntireRow.Delete
       Next lngIndex
   End Sub